[src/trunk]: src/lib/libc/arch/m68k/string Implement a significantly improved...

[scottr <scottr%NetBSD.org@localhost>]

details:   https://anonhg.NetBSD.org/src/rev/92635ee4bb33
branches:  trunk
changeset: 503349:92635ee4bb33
user:      scottr <scottr%NetBSD.org@localhost>
date:      Mon Feb 05 00:17:22 2001 +0000

description:
Implement a significantly improved version of memccpy(), with thanks to
Ignatios Souvatzis for correcting the SVR4 ABI code and for a few
micro-optimizations that followed from these changes.

The overall improvement was measured at 3-4x for copies of at least
4 bytes on the 68030, and 8 bytes on the 68040.  For smaller copies
the improvement was still measurable, if not as dramatic.

diffstat:

 lib/libc/arch/m68k/string/memccpy.S |  82 +++++++++++++++++++++++++++++++++++++
 1 files changed, 82 insertions(+), 0 deletions(-)

diffs (86 lines):

diff -r 7b607ed6c900 -r 92635ee4bb33 lib/libc/arch/m68k/string/memccpy.S
--- /dev/null   Thu Jan 01 00:00:00 1970 +0000
+++ b/lib/libc/arch/m68k/string/memccpy.S       Mon Feb 05 00:17:22 2001 +0000
@@ -0,0 +1,82 @@
+/*     $NetBSD: memccpy.S,v 1.1 2001/02/05 00:17:22 scottr Exp $       */
+
+/*
+ * Copyright (C) 1999 Scott Reynolds.  All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. The name of the author may not be used to endorse or promote products
+ *    derived from this software without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
+ * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
+ * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
+ * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+ * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+ * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+ * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
+ * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+
+#if defined(LIBC_SCCS) && !defined(lint)
+       RCSID("$NetBSD: memccpy.S,v 1.1 2001/02/05 00:17:22 scottr Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+ENTRY(memccpy)
+       movl    %sp@(16),%d0            | count
+       jeq     Lmcbail                 | nothing to do
+
+       movl    %sp@(4),%a0             | a0 = toaddr
+       subql   #1,%d0                  |   prepare count for DBcc loop
+       movl    %sp@(8),%a1             | a1 = fromaddr
+       movl    %sp@(12),%d1            | d1 = terminator
+       jeq     Lmcloop                 |   handle ASCII NUL specially
+
+       movl    %d2,%sp@-               | save scratch register
+Lmcnzloop:
+       movb    %a1@+,%d2               | move a byte
+       movb    %d2,%a0@+
+       cmpb    %d2,%d1                 | found the terminator?
+       dbeq    %d0,Lmcnzloop           | if not, keep transferring,
+       jeq     Lmcnzdone               |   otherwise done
+       clrw    %d0                     | check to see if more to do
+       subql   #1,%d0
+       jcc     Lmcnzloop               | yes, keep going...
+
+       movl    %sp@+,%d2               | restore scratch register
+       movql   #0,%d0                  | no terminator found, return NULL
+#ifdef __SVR4_ABI__
+       movl    %d0,%a0                 | XXX maybe use lea to avoid stall?
+#endif
+       rts
+
+Lmcloop:
+       movb    %a1@+,%a0@+             | move a byte; was it NUL?
+       dbeq    %d0,Lmcloop             | if not, keep transferring,
+       jeq     Lmcdone                 |   otherwise done
+       clrw    %d0                     | check to see if more to do
+       subql   #1,%d0
+       jcc     Lmcloop                 | yes, keep going...
+                                       | Note: %d0 is now -1!
+       movql   #0,%d0                  | no terminator found, return NULL
+Lmcbail:
+#ifdef __SVR4_ABI__
+       movl    %d0,%a0                 | XXX maybe use lea to avoid stall?
+#endif
+       rts
+
+Lmcnzdone:
+       movl    %sp@+,%d2               | restore scratch register
+Lmcdone:
+       movl    %a0,%d0
+       rts