[src/trunk]: src/sys/arch/evbarm/stand/gzboot/TS7200_flash_0x60660000 support...

[joff <joff%NetBSD.org@localhost>]

details:   https://anonhg.NetBSD.org/src/rev/8d4e043824c7
branches:  trunk
changeset: 572202:8d4e043824c7
user:      joff <joff%NetBSD.org@localhost>
date:      Fri Dec 24 10:32:40 2004 +0000

description:
support for gzimg's in TS-7200 Redboot on-board flash

diffstat:

 sys/arch/evbarm/stand/gzboot/TS7200_flash_0x60660000/Makefile |  17 ++
 sys/arch/evbarm/stand/gzboot/TS7200_flash_0x60660000/ldscript |  83 +++++++++++
 2 files changed, 100 insertions(+), 0 deletions(-)

diffs (108 lines):

diff -r 82cd25bb3663 -r 8d4e043824c7 sys/arch/evbarm/stand/gzboot/TS7200_flash_0x60660000/Makefile
--- /dev/null   Thu Jan 01 00:00:00 1970 +0000
+++ b/sys/arch/evbarm/stand/gzboot/TS7200_flash_0x60660000/Makefile     Fri Dec 24 10:32:40 2004 +0000
@@ -0,0 +1,17 @@
+#      $NetBSD: Makefile,v 1.1 2004/12/24 10:32:40 joff Exp $
+
+S=     ${.CURDIR}/../../../../..
+
+PLATFORM= TS7200
+RELOC= 0x60660000
+MAXIMAGESIZE= 0                # concatenate
+LOADADDR= 0x00200000
+
+CPPFLAGS+= -DCONSPEED=115200
+CPPFLAGS+= -DCONADDR=0x808c0000UL
+
+LDSCRIPT= ${.CURDIR}/ldscript
+
+SRCS+= ts7200.c epcom.c
+
+.include "${S}/arch/evbarm/stand/gzboot/Makefile.gzboot"
diff -r 82cd25bb3663 -r 8d4e043824c7 sys/arch/evbarm/stand/gzboot/TS7200_flash_0x60660000/ldscript
--- /dev/null   Thu Jan 01 00:00:00 1970 +0000
+++ b/sys/arch/evbarm/stand/gzboot/TS7200_flash_0x60660000/ldscript     Fri Dec 24 10:32:40 2004 +0000
@@ -0,0 +1,83 @@
+/*     $NetBSD: ldscript,v 1.1 2004/12/24 10:32:40 joff Exp $  */
+
+OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm",
+             "elf32-littlearm")
+OUTPUT_ARCH(arm)
+ENTRY(FLASH)
+MEMORY
+{
+  /* We will locate the .text section in flash, and will run directly
+     from there just long enough to relocate our .text and .data into
+     a small chunk of SDRAM starting at (SDRAM + 1M).  */
+  flash : o = 0x60660000, l = 1408K
+  sdram : o = 0x00100000, l = 1M       /* kernel loads at 0x00200000 */
+}
+SECTIONS
+{
+  FLASH = 0x60660000;
+
+  /* Read-only sections, merged into text segment: */
+  __text_store = FLASH;
+  .text      :
+  AT (FLASH)
+  {
+    *(.text)
+    *(.text.*)
+    *(.stub)
+    *(.glue_7t) *(.glue_7)
+    *(.rodata) *(.rodata.*)
+  } > sdram =0
+  PROVIDE (__etext = .);
+  PROVIDE (_etext = .);
+  PROVIDE (etext = .);
+  __data_store = FLASH + SIZEOF(.text);
+  .data    :
+  AT (LOADADDR(.text) + SIZEOF(.text))
+  {
+    __data_start = . ;
+    *(.data)
+    *(.data.*)
+  } > sdram
+  .sdata     : 
+  AT (LOADADDR(.data) + SIZEOF(.data))
+  {
+    *(.sdata) 
+    *(.sdata.*)
+    . = ALIGN(32 / 8);
+  } > sdram
+  _edata = .;
+  PROVIDE (edata = .);
+  __bss_start = .;
+  __bss_start__ = .;
+  .sbss      :
+  {
+    PROVIDE (__sbss_start = .);
+    PROVIDE (___sbss_start = .);
+    *(.dynsbss)
+    *(.sbss)
+    *(.sbss.*)
+    *(.scommon)
+    PROVIDE (__sbss_end = .);
+    PROVIDE (___sbss_end = .);
+  } > sdram
+  .bss       :
+  {
+   *(.dynbss)
+   *(.bss)
+   *(.bss.*)
+   *(COMMON)
+   /* Align here to ensure that the .bss section occupies space up to
+      _end.  Align after .bss to ensure correct alignment even if the
+      .bss section disappears because there are no input sections.  */
+   . = ALIGN(32 / 8);
+  } > sdram
+  . = ALIGN(32 / 8);
+  _end = .;
+  _bss_end__ = . ; __bss_end__ = . ; __end__ = . ;
+  PROVIDE (end = .);
+  .image   (FLASH + SIZEOF(.text) + SIZEOF(.data) + SIZEOF(.sdata)) :
+  AT (LOADADDR(.sdata) + SIZEOF(.sdata))
+  {
+    *(.image)
+  }
+}